强度类指标源码

进入正篇前先设好四套基础指标：SSV、RSL、RSR、RSV。SSV 与 RSL 用成交量加权（见第三节），RSR 电脑端用扩展数据、手机端用 RSV 替代（见第二节）；手机用户用 RSV 平替。欧马体系对基本面有要求，可先用预选股池（见第 24 节）过滤；只做堆量模型则无此要求，可省。

设好基础指标，用「领先股池」选股器选出当下整体强势股。要缩小清单，加短期动量条件，用 OVS 或 RS_D 做低吸或突破股池。再叠毒股三式，流程就通了。

短期动量两种思路。着眼突破，动量「先小后大」；着眼伏击，动量「先大后小」。两者相反，无对错，理论与实战都有人用。信口袋支点，就是要求短期动量「由小变大」。

领先股池三种写法。第一种只适用于电脑、用扩展数据；第二种也只适用于电脑但不用扩展数据（用 RSV 替代）；第三种是手机用户，因软件限制无法叠加行业强度，清单明显更多。

RSRHY:=CALCSTOCKINDEX(HYZSCODE,'RSR行业',2);

RSR个股.RSR>85 AND RSL.RSL2>100 AND RSRHY>60;

RSVHY:=CALCSTOCKINDEX(HYZSCODE,'RSV',3);

RSV.RSVA>74 AND RSV.RSV1>85 AND RSV.RUN1>=70 AND RSVHY>70;

RSV.RSVA>74 AND RSV.RSV1>85 AND RSV.RUN1>=70;

两种方式选股有差异，数量随行情增减。手机版缺行业强度约束，数量明显更多。

弄清长周期与短周期强度含义后，选股很简单，调强度阈值即得想要区间。猛兽动量体系形态契合度远胜陶派 RPS，基本不漏牛股及初始启动。

短期动量指标从整体强势中切出「短期低波动小群」做低吸备选；突破思路反之。猛兽动量系统的短期动量指标主要是 OVS 和 RS_D。

低吸股池要求强势中、短期低波动：前置 PV 够大、现在 PV 回落低位、RS_D 背离值 DRA 小、成交额不放大（SBL 约束）。

RSVHY:=CALCSTOCKINDEX(HYZSCODE,'RSV',3);
ALLQS:=RSV.RSV>74 AND RSVHY>70;

PV2:=OVS.PV2;
PV3:=OVS.PV3;
PVA:=ABS(PV2);
QZPV:=HHV(PV3,10)>12;{前置PV}
XZPV:=PVA<6;{现在PV}

DR:=RS_D.DR;
DRA:=ABS(DR);
XZDR:=DRA<15;

SBL:=AMO<HHV(AMO,22)*0.6;

ALLQS AND QZPV AND XZPV AND XZDR AND SBL;

突破思路反过来描述，更直接：前置 PV 取近两日低位、现在 PV 放大。

RSVHY:=CALCSTOCKINDEX(HYZSCODE,'RSV',3);
ALLQS:=RSV.RSV>74 AND RSV.RSV1>85 AND RSVHY>74;

PV2:=OVS.PV2;
PV3:=OVS.PV3;
PVA:=ABS(PV2);
QZPV:=LLV(REF(PVA,1),2)<6;{前置PV}
XZPV:=PV3>12;{现在PV}

ALLQS AND QZPV AND XZPV;

枢轴点股池从 M8 调取选股很慢，建议单独摘出（见第 24 节）。堆量选股另用一套工具。再叠毒股三式即完整。

RSR 起因是陶派 RPS 长周期滞后，20/50 日拟合仍有错位。为契合背景强度与形态反转支点，摸索很久才定方案。核心：涨幅越大越强是错的，强度要同时算上涨与回撤，即多空综合。大量回测表明标准化强度最合理有效。

2.0 版只留一条扩展数据，只对 SSV 做；RSV 横向比较用另法（见第四节）。分三步：

1. 先建 SSV 基础公式与 RSV 基础公式，供扩展数据与 RSR 指标调用。
2. 创建扩展数据：选一条空白数据行（示范用序号 1），按图设置勾选项并刷新。
3. 新建「RSR个股」副图指标，粘贴下方代码，公式名须与图一致；行业 RSR 同理用序号 5。

个股 RSR 的算式 RSR:(SSV1*0.6+RSVA*0.4) 在稳定和灵敏度间找平衡，两个加权系数可调节，但加起来须等于 1。

W1:=EXTDATA_USER(1,0);
SSV1:W1/10,LINETHICK1,COLORLICYAN,NODRAW;

RSVA:RSV.RSVA,COLORLIGREEN,NODRAW;

RSR:(SSV1*0.6+RSVA*0.4),LINETHICK2,COLOR804000;
IF(RSR>=N,RSR,DRAWNULL),LINETHICK2,COLORC080FF;
IF(RSR>=M,RSR,DRAWNULL),LINETHICK2,COLORRED;

MID:50,DOTLINE,COLORGRAY;

行业 RSR 设置与个股几乎一样，计算品种需自定义（行业指数做成自定义板块再导入）。行业 RSR 用等权 RSR:(SSV1+RSVA)/2，也可改个股那样的不等权。

W1:=EXTDATA_USER(5,0);
SSV1:W1/10,LINETHICK1,COLORBROWN;

RSVA:RSV.RSVA,COLORGRAY;

RSR:(SSV1+RSVA)/2,LINETHICK2,COLOR804000;
IF(RSR>=N,RSR,DRAWNULL),LINETHICK2,COLORC080FF;
IF(RSR>=M,RSR,DRAWNULL),LINETHICK2,COLORRED;

MID:50,DOTLINE,COLORGRAY;

补充自定义板块设置：通达信界面输入「BK」回车打开设置界面，新建可识别文件夹即建板块；右键「批量处理」把数据导入新板块。行业 RSR 可关联三级行业（颗粒更细、易锁定目标），但难度高，不建议公式小白试。

成交量加权构造价格曲线，若用 SUM(AMO,N)/SUM(V,N)，复权后曲线飞离 K 线，因配送股成交量不能跟随。沿用《趋势为金》，用 AMO 作量柱：SUM(AMO*C,N)/SUM(AMO,N)，不怕复权。

成交量加权均线即真实成本价格，周期内平均持仓成本；偏离越快，强弱变化越快，这是 SSV 基本定义。保留两种归一化，得 SSV：

VWAP:=SUM(AMO*C,N)/SUM(AMO,N);
STDD:=SQRT(SUM(POW((C-VWAP),2),N)/(N-1));
SSV1:(C-VWAP)/VWAP*100;
SSV2:(C-VWAP)/STDD*100,NODRAW;
SSVA:MA(SSV1,13);

ZRO:0,DOTLINE;

对 RS Line 同样加权，得《笑傲牛熊》的 RS 曲线，比 MA 均值更合理：

RS:=CLOSE/"880003$CLOSE";
VWRS:=SUM(RS*AMO,N)/SUM(AMO,N);
STDD:=SQRT(SUM(POW((RS-VWRS),2),N)/(N-1));
RSL1:(RS-VWRS)/VWRS*100;
RSL2:(RS-VWRS)/STDD*100,NODRAW;
RSLA:MA(RSL1,13);

ZRO:0,DOTLINE;

SSV 和 RSL 是典型动量指标，能度量强弱，也能用峰峰、谷谷背离评估趋势转折，原理同 BIAS。本次更新隐匿 SSV2 与 RSL2，增 SSV1 与 RSL1 的均值输出。

陶博士称为看家绝技的 RPS 有个重大缺陷：长周期滞后太多。副图黄线即陶派 RPS，周期 250 日、阈值 88，强度进 88 与退 88 对应股价滞后太多，回撤超 50% 时 RPS 仍显示近 100，可信度很低。

问题出在数学。陶公式 EXRT:(C-REF(C,N))/REF(C,N) 输出可无限大；RSV 输出只在 0~100，且含多空力量，C-LLV(L,N) 越小回撤越大。从可信度看，强度必须算空方即回撤因子。

EXRT: (C-REF(C,N))/REF(C,N);
RSV: (C-LLV(L,N))/(HHV(H,N)-LLV(L,N))*100;

RSV 源自 KDJ，KDJ 来自威廉指标。威廉算最高价回撤，RSV 算最低价涨幅，最大振幅内两者一样，曲线相反，倒过来重合。直接用 RSV 平替 RPS，降难度，简单有效。

做法：新建公式把 N 设到 250，阈值 75 较合理，暗合「股价处在一年新高 75% 以上」。经扩展数据即全市场比较（外部强度），不经由是内部比较，两者走向一致不错。

不做扩展数据，还有更直接思路：对 RS Line 做类似 RSV 归一化再整合，得 RSVA:=(RSV1+RSV2)/2。RSVA 紫显 >=75、红显 >=85，阈值与 RSR 一致，免扩展数据、可盘内实时、手机可用，不拖累响应。

有了相对强度，自然问绝对强度。陶公式 EXTR:(C-REF(C,N))/REF(C,N) 表 N 日动态涨幅。但 50% 涨幅弱于 100% 显然不对，涨越多越强难道永远涨？上涨获利盘累积，卖出倾向也累积，后期波动大；低位启动前波动收窄。波动程度即风险，上涨强势因子需波动风险因子惩罚或奖励。

用标准差描述波动：SD:STD(C,N)，推升时变大、收敛极限趋于 0。强度用线性回归动态斜率：SLOP:SLOPE(C,N)，斜率有正负。

方法一，用标准差倒数乘强度值作惩罚/奖励：

STR:=SUM(TR,N),NODRAW;
HL:=(HHV(H,N)-LLV(L,N));
CHOP:=LOG(STR/HL)/LOG(N);
SD:=STD(C,N);
SLOP:=SLOPE(C,N);
CPRS:SLOP*CHOP*N*10;
SDRS:SLOP/SD*N*10;
ZERO:0,DOTLINE;

SDRS:SLOP/SD*N*10 经惩罚奖励后，低位也可高强度，高点却背离。方法二借 Dreiss 的 CHOP：CHOP:LOG(STR/HL)/LOG(N)*10，累加真实波幅再除最大波动范围，范围越小输出越大。它引入「最大波动范围」，即结构紧凑。CPRS:SLOP*CHOP*N*10 结合两者。

以上绝对强度思路未在实战应用过，只发表供有心人研究。

成交量反映多空分歧与流动性，非直接指向涨跌，量价无必然关系。最常用 OBV，按涨跌累加：

VA:=IF(CLOSE>REF(CLOSE,1),VOL,-VOL);
OBV:SUM(IF(CLOSE=REF(CLOSE,1),0,VA),0);
WVAD:SUM(VOL*(CLOSE-OPEN)/(HIGH-LOW),N);
VPT:SUM(VOL*(CLOSE-REF(CLOSE,1))/REF(CLOSE,1),N);
MIDA:=CLOSE-MIN(REF(CLOSE,1),LOW);
MIDB:=IF(CLOSE<REF(CLOSE,1),CLOSE-MAX(REF(CLOSE,1),HIGH),0);
WAD:SUM(IF(CLOSE>REF(CLOSE,1),MIDA,MIDB),0);

WVAD 思路同 OBV，但对每日成交量加权，比 VPT 直接乘涨跌幅更合理。它有两个问题：一字板开收高低全等，分子分母皆 0；且完全不考虑昨日因素（OBV、VPT 都含昨日）。WAD 引入昨日收盘价参与计算，更科学。

综合威廉姆斯思路改进 OBV：先加权提取日内成交量，再归一化提取多空合力作加权值：

HG:=MAX(H,REF(C,1));
LW:=MIN(L,REF(C,1));
OV:SUM(V*(C-REF(C,1))/(HG-LW),0);
MAOV: MA(OV,N1);

N1 设为 30。优劣自行判断。

威廉姆斯在《选股密码》和《我如何赚取100万美元》都讲了这个公式，被称百万美元公式。先提取当日 K 线多空力度乘成交量再累加。BSR 分子是收盘价-开盘价，分母是最高价-最低价（波及最大范围），多方胜为正、空方胜为负；乘成交量后正值被吸、负值被吐，吸筹派发即此意。

威廉姆斯加法两种：上市首日累加（OBV 搞法），或区间累加（通达信缺省）。应是第二种，OBV 难提背离，背离才是核心。改进 VAD 画线与原版几乎一样但更准：

HI:=MAX(H,REF(C,1));
LW:=MIN(L,REF(C,1));
BSR:=(C-REF(C,1))/(HI-LW);
VAD:SUM(BSR*VOL,N);
WOV:WMA(VAD,M);

吸筹派发线取背离信号，同动量背离。熊市 RS Line 抗跌背离再叠吸筹派发底背离，上涨概率明确。底背离机构在吸筹，顶背离在派发，但非百分百。

买卖时机层层递进：趋势模板最基础，细节在其上。马克趋势模板核心 C>MA(C,50) 且 C>MA(C,150) 且 C>MA(C,200)，即股价在三条均线之上；它只是背景，不排除阶段头部与总头部，买卖时机未定义。

副图 RSR 用 RSV 定义，RPS>87 标红；趋势模板赋值 1 表示符合，黄点即口袋支点。RSR 250 周期翻红基本是全部右侧趋势，去均线定义也不影响。RSR 反映动量、均线反映成本，交叉后更严谨；陶派 RPS 难配口袋支点，正因如此。

标准化强度归总印证：RSV 解陶派 RPS 滞后，但被认为削弱涨幅惯性；取 SCI 为基准兼顾 RSV 灵敏，用两者做 233 日 RPS。SSV>0 AND RSL>0 限长期背景，集体下坠时 RSL 可正仍跌，上涨时 RSL>0 才有效。

RS Line 是板块与大盘比值，反映板块下跌动量衰竭。底背离即板块跟跌但跌幅小于大盘，预示反转；持续抬升即强势蓄能。RSR 应攀升超 90、频现 TOP10，印证走强。通信、医药、汽车、减速器均有案例。

熊市末端同样适用：RS Line 与平均股价大级别底背离，预示机构逆势建仓；叠加新领导上任与前置动量，第一波涨幅超 50% 为佳（统计一般 40%~120%，多一气呵成）。